设置技能快捷键命令

---

设置技能快捷键命令

TJ_SetMagicHotKey 参数1 参数2

参数位置	参数说明
参数1	技能ID 或 技能名字
参数2	技能快捷键【(F1 - F8：49-56) / (Ctrl+F1-F8：69-76)】

[@测试]
#IF
CHECKLEVELEX > 0
#ACT
TJ_SetMagicHotKey 烈火剑法 49
SENDMSG 5 烈火剑法快捷键设置为：F1
break

[@测试]
#IF
CHECKLEVELEX > 0
#ACT
TJ_SetMagicHotKey 11 69
SENDMSG 5 雷电术快捷键设置为：Ctrl+F1
break

脚本示范：删除技能后重新学技能设置原始快捷键

<删除所有技能/@删除所有技能>\
<重新学习技能/@重新学习技能>\

[@删除所有技能]
#IF
LARGE <$MAGICCOUNT> 0
#ACT
MOV N$数值 0
TJ_LoopGoTo @记录技能快捷键 <$MAGICCOUNT>
CLEARSKILL
break
#ELSEACT
SENDMSG 5 您并未学习任何技能...
break

[@记录技能快捷键]
#IF
CHECKLEVELEX > 0
#ACT
TJ_WriteConfigFileItemEx ..\QuestDiary\技能快捷键.txt <$USERNAME> <$MAGICLIST[<$STR(N$数值)>].NAME> <$MAGICLIST[<$STR(N$数值)>].HOTKEY>
INC N$数值 1
break

[@重新学习技能]
#IF
CHECKLEVELEX > 0
#ACT
ADDSKILL 基本剑术 3
ADDSKILL 攻杀剑术 3
ADDSKILL 刺杀剑术 3
ADDSKILL 半月弯刀 3
ADDSKILL 野蛮冲撞 3
ADDSKILL 烈火剑法 3
MOV N$数值 0
TJ_LoopGoTo @写入技能快捷键 <$MAGICCOUNT>
break

[@写入技能快捷键]
#IF
CHECKLEVELEX > 0
#ACT
TJ_ReadConfigFileItemEx ..\QuestDiary\技能快捷键.txt <$USERNAME> <$MAGICLIST[<$STR(N$数值)>].NAME> <$STR(N$快捷键)>
TJ_SetMagicHotKey <$MAGICLIST[<$STR(N$数值)>].NAME> <$STR(N$快捷键)>
INC N$数值 1
break